#!/bin/csh -- -*- shell-script -*-
#
# MPI/LAM Standard .cshrc file
# Sould only be sourced!  Should not replace your .cshrc file!
#
# This script sets your TROLLIUSHOME (which is the same as LAMHOME)
# variable and selects the right path for the LAM binaries to put 
# in your path, depending on the following:
#
# - which compiler you are using (really only relevant for C++)
# - what architecture you are on
#

#
# Shortcuts for below
# We have a LAM_VERSION variable because we have several versions
# of LAM online (for development, stability, etc.).
#

set LAM_VERSION=6.3
set TOP=/afs/nd.edu/user37/ccse
set LAM=mpi/lam-$LAM_VERSION

#
# Architecture dependent stuff
# Use the GNU config.guess to get type of machine
#

set LAM_ARCH=`$TOP/mpi/config.guess`
set UNAME_ARCH=`echo $LAM_ARCH | cut -d- -f1`
set UNAME_SYSTEM=`echo $LAM_ARCH | cut -d- -f2`
set UNAME_OS=`echo $LAM_ARCH | cut -d- -f3`

set PREFIX_PATH=
set SUFFIX_PATH=
set TROLLIUSHOME=

#
# We have several versions of LAM/MPI available, and it is possible
# to source this script after one version of LAM has already been
# set in the path.  So if we are sourcing this script, ensure to
# remove all other LAM/MPI versions from the path.
#

set new_path=
foreach entry ($path)
    set new=$entry

    if ("$new" =~ $TOP/mpi/*) then
	set new=
    endif

    set new_path=($new_path $new)
end


#
# Which compiler do we want?  This is only really relevant for different
# C++ compilers.  If you are not planning on using C++, this part is
# not really necessary.
#

if ("$?CC" == "1") then
    set C_COMPILER=`basename $CC`
else
    set C_COMPILER=
endif

if ("$?CXX" == "1") then
    set CPP_COMPILER=`basename $CXX`
else
    set CPP_COMPILER=
endif


#
# Do we want the compiler warning message or not?
#

if ("$?MPI_WARN" == "1") then
    set CAT=cat
else
    set CAT=":"
endif

set errfile=/tmp/lam_cshrc_err.$$
/bin/rm -f $errfile
cat > $errfile <<EOF
 
********************************* WARNING *********************************

lam_cshrc could not determine which C/C++ compilers that you wanted to use.
Either your CC/CXX environment variables are not set, or they are not set
to the same brand of vendor.

********************************* WARNING *********************************


EOF

#
# Now figure out which architecutre we're on.  Use the result of the
# GNU config.guess script.
#
# The structure of each of the following cases is very similar: 
#
# - Determine which C/C++ compiler we want and set environment variables
# accordingly.  Default to some compiler (usually the native compiler)
# if the user has not specified in their environment which one they want.
#
# - Set the LAMHCC, LAMHCP, and LAMHF77 environemnt variables according
# to which compiler was chosen.
#
# - Set the TROLLIUSHOME (equivalent to the LAMHOME variable) environment
# variable to the path of the specific tree for that architecture
# and compiler.
#

switch ("$LAM_ARCH")
    case "sparc-sun-solaris2.5":
    case "sparc-sun-solaris2.5.1":
    case "sparc-sun-solaris2.6":

	#
	# Solaris 2.5, 2.5.1 and 2.6
	#

        if ("$C_COMPILER" == "cc" || ("$C_COMPILER" == "" && "$CPP_COMPILER" == "CC")) then
	    set COMPILER=workshop
	    set C=cc
	    set CPP=CC
	else if ("$C_COMPILER" == "KCC" || ("$C_COMPILER" == "" && "$CPP_COMPILER" == "KCC")) then
	    set COMPILER=kai
	    set C=KCC
	    set CPP=KCC
        else if ("$C_COMPILER" == "gcc" || ("$C_COMPILER" == "" && "$CPP_COMPILER" == "g++")) then
	    set C=gcc
	    set CPP=g++
	    set out=`gcc --version | grep egcs | grep -v grep`
	    if ("$out" == "") then
		set COMPILER=gnu
	    else
		set COMPILER=egcs
	    endif
	else
	    $CAT <<EOF 
`cat $errfile`
Defaulting to the Solaris Workshop compilers.

EOF
	    set COMPILER=workshop
	    set C=cc
	    set CPP=CC
        endif


        set TROLLIUSHOME=$TOP/$LAM/$LAM_ARCH/$COMPILER
	set PREFIX_PATH="$PREFIX_PATH $TROLLIUSHOME/bin"

	setenv LAMHCC $C
	setenv LAMHCP $CPP
	setenv LAMHF77 f77

	limit descriptors 128

	breaksw

    case "rs6000-ibm-aix4.1*":
    case "rs6000-ibm-aix4.2*":
    case "powerpc-ibm-aix4.2*":

        #
        # AIX 4.1.x/4.2*
        #

	if (("$C_COMPILER" == "cc" || ("$C_COMPILER" == "" && "$C_COMPILER" == "xlc")) && \
            "$CPP_COMPILER" == "xlC") then
            set COMPILER=cset
            set C=xlc
            set CPP=xlC
	else if (("$C_COMPILER" == "cc_r" || ("$C_COMPILER" == "" && "$C_COMPILER" == "xlc_r")) && \
            "$CPP_COMPILER" == "xlC_r") then
            set COMPILER=cset_r
            set C=xlc_
            set CPP=xlC_r
        else if ("$C_COMPILER" == "gcc" || ("$C_COMPILER" == "" && "$CPP_COMPILER" == "g++")) then
            set C=gcc
            set CPP=g++
            set out=`gcc --version | grep egcs | grep -v grep`
            if ("$out" == "") then
                set COMPILER=gnu
            else
                set COMPILER=egcs
            endif
        else
            $CAT <<EOF
`cat $errfile`
Defaulting to the AIX C Set compilers.

EOF
            set COMPILER=cset
            set C=xlc
            set CPP=xlC
        endif

        set TROLLIUSHOME=$TOP/$LAM/$LAM_ARCH/$COMPILER
        set SUFFIX_PATH="$SUFFIX_PATH $TROLLIUSHOME/bin"

        setenv LAMHCC $C
        setenv LAMHCP $CPP
        setenv LAMHF77 xlf

        breaksw

    case "mips-sgi-irix6.2":
    case "mips-sgi-irix6.3":
    case "mips-sgi-irix6.4":

	#
	# IRIX 6.2, 6.3, 6.4
	#

	# No other compilers are supported yet:
	# gnu stuff makes crappy code and isn't availble on AFS
	# KCC doesn't work (strict type checking, etc.)

	set COMPILER=mipspro
	set C=cc
	set CPP=CC

        set TROLLIUSHOME=$TOP/$LAM/$LAM_ARCH/$COMPILER
	set SUFFIX_PATH="$SUFFIX_PATH $TROLLIUSHOME/bin"

	setenv LAMHCC $C
	setenv LAMHCP $CPP
	setenv LAMHF77 f77

	breaksw

    case "i*86-pc-linux-gnu"

        #
	# Linux
	# Only one compiler here
	#
   
	set COMPILER=gnu
	set C=gcc
	set CPP=g++

	set TROLLIUSHOME=$TOP/$LAM/$LAM_ARCH/$COMPILER

	setenv LAMHCP g++
	setenv LAMHCC gcc

	set PREFIX_PATH="$TROLLIUSHOME/bin"

	breaksw

    default:

	#
	# Who the heck knows?
	#

	echo "UNKNOWN Architecture: $LAM_ARCH"
	echo "LAM/MPI not configured"

        breaksw
endsw

#
# Remove the temp warning file
#

/bin/rm -f $errfile


#
# It's helpful to know where the root of your MPI tree is
# Set it now; use it later
#

set MPIROOT=$TROLLIUSHOME


#
# Set the path
#

set path = ( $PREFIX_PATH $new_path $SUFFIX_PATH )


#
# Put in the MPI man pages, but only if it's not already in the MANPATH.
# Notice that there's only *one* copy of the man pages, regardless of
# architecture/compiler/etc.
#

set mpath=$TOP/mpi/lam/man
if ("$?MANPATH" == 0) then
    setenv MANPATH $mpath
else if ("`echo $MANPATH | grep $mpath`" == "") then
    setenv MANPATH ${mpath}:$MANPATH
endif

#
# Helpful aliases
#
# The -c2c option is not necessary for LAM 6.2.x, but we do it for 
# explicit clarity anyway.  The "lamrun2" alias is for 2-way SMP's 
# (which we have a lot of, so it's useful for us).  
#
# Additionally, the -w and -D options are no longer necessary for 
# the LAM 6.3 series, but we keep them here for hysterical raisins.
#

alias   lamrun          $TROLLIUSHOME/bin/mpirun -c2c -O -w N -D \`pwd\`/!\*
alias   lamrun2         $TROLLIUSHOME/bin/mpirun -c2c -O -w N N -D \`pwd\`/!\*